Optic Data Manipulation Starter Pack

xquery version "1.0-ml";
import module namespace op = "http://marklogic.com/optic" at "/MarkLogic/optic.xqy";
import module namespace ofn = "http://marklogic.com/optic/expression/fn" at "/MarkLogic/optic/optic-fn.xqy";
import module namespace oxs = "http://marklogic.com/optic/expression/xs" at "/MarkLogic/optic/optic-xs.xqy";
import module namespace oxdmp = "http://marklogic.com/optic/expression/xdmp" at "/MarkLogic/optic/optic-xdmp.xqy";

let $captured-at := fn:current-dateTime()
let $_ := xdmp:sleep(5000)
let $captured := op:from-literals((
  map:entry("demoId", "runtime-proof")
    => map:with("capturedAt", $captured-at)
))
let $runtime := op:from-literals((
  map:entry("runtimeId", "runtime-proof")
))

return
$captured
  => op:join-cross-product(
       $runtime,
       op:eq(op:col("demoId"), op:col("runtimeId"))
     )
  => op:select((
       "demoId",
       "capturedAt",
       op:as("runtimeAt", ofn:current-dateTime()),
       op:as("runtimeAsDateTime", oxs:dateTime(ofn:string(ofn:current-dateTime()))),
       op:as("runtimeAfterCaptured", op:gt(ofn:current-dateTime(), op:col("capturedAt"))),
       op:as("runtimeRandom", oxdmp:random(1000000))
     ), "clockCheck")
  => op:result()

xquery version "1.0-ml";
import module namespace op = "http://marklogic.com/optic" at "/MarkLogic/optic.xqy";
import module namespace ofn = "http://marklogic.com/optic/expression/fn" at "/MarkLogic/optic/optic-fn.xqy";

let $forestDoc := document {
  element all-forests {
    for $forest in subsequence(xdmp:forest-status(xdmp:forests()), 1, 3)
    return $forest
  }
}

let $descriptors :=
  for $forest at $position in $forestDoc/*:all-forests/*:forest-status
  return
    map:entry("uri", "/cleverllamas/llamaverse/scratch/reports/forest-status-" || $position || ".xml")
      => map:with("doc", document { $forest })

return
op:from-doc-descriptors($descriptors)
  => op:select((
       "uri",
       op:as("forestName", ofn:string(op:xpath("doc", "/*:forest-status/*:forest-name"))),
       op:as("availability", ofn:string(op:xpath("doc", "/*:forest-status/*:availability"))),
       op:as("state", ofn:string(op:xpath("doc", "/*:forest-status/*:state")))
     ))
  => op:result()

xquery version "1.0-ml";
import module namespace op = "http://marklogic.com/optic" at "/MarkLogic/optic.xqy";
import module namespace ofn = "http://marklogic.com/optic/expression/fn" at "/MarkLogic/optic/optic-fn.xqy";

let $descriptors := (
  map:entry("uri", "/llama/skills/aaron.xml")
    => map:with("doc", xdmp:unquote('<llama><name>Aaron</name><skills><skill>xpath</skill><skill>optic</skill></skills></llama>')),
  map:entry("uri", "/llama/skills/cameron.xml")
    => map:with("doc", xdmp:unquote('<llama><name>Cameron</name><skills><skill>xpath</skill><skill>security</skill><skill>optic</skill></skills></llama>'))
)

return
op:from-doc-descriptors($descriptors)
  => op:select((
       "uri",
       op:as("llamaName", ofn:string(op:xpath("doc", "/llama/name"))),
       op:as("skillSeq", op:xpath("doc", "/llama/skills/skill/text()"))
     ))
  => op:unnest-inner("skillSeq", "skill", "skillOrdinality")
  => op:order-by((op:asc("llamaName"), op:asc("skillOrdinality")))
  => op:result()

xquery version "1.0-ml";
import module namespace op = "http://marklogic.com/optic" at "/MarkLogic/optic.xqy";
import module namespace ofn = "http://marklogic.com/optic/expression/fn" at "/MarkLogic/optic/optic-fn.xqy";

op:from-literals((
  map:entry("name", "Aaron")
    => map:with("breed", "Huacaya")
    => map:with("heightCm", 172)
    => map:with("placeOfBirth", "Cusco"),
  map:entry("name", "Cameron")
    => map:with("breed", "Suri")
    => map:with("heightCm", 167)
    => map:with("placeOfBirth", "Quito"),
  map:entry("name", "Richard")
    => map:with("breed", "Huacaya")
    => map:with("heightCm", 176)
    => map:with("placeOfBirth", "Arequipa")
))
  => op:select((
       op:as("llamaName", op:col("name")),
       op:as("profileLabel", ofn:concat((op:col("name"), " (", op:col("breed"), ") from ", op:col("placeOfBirth")))),
       op:as("heightCm", op:col("heightCm")),
       op:as("isTall", op:gt(op:col("heightCm"), 170))
     ), "shape")
  => op:order-by(op:asc("llamaName"))
  => op:result()

xquery version "1.0-ml";
import module namespace op = "http://marklogic.com/optic" at "/MarkLogic/optic.xqy";
import module namespace ofn = "http://marklogic.com/optic/expression/fn" at "/MarkLogic/optic/optic-fn.xqy";
declare option xdmp:update "true";

let $user-name := "cleverllamas-mother"
let $privilege-csv := fn:string-join(
  for $privilege-id in xdmp:user-privileges($user-name)
  return fn:string($privilege-id),
  ","
)

let $privilege-rows :=
  op:from-literals((
    map:entry("userName", $user-name)
      => map:with("privilegeCsv", $privilege-csv)
  ))
    => op:bind((
         op:as("privilegeSeq", ofn:tokenize(op:col("privilegeCsv"), ","))
       ))
    => op:unnest-inner("privilegeSeq", "privilegeId", "ordinality")
    => op:select(("userName", "privilegeId", "ordinality"))
    => op:result()

let $rows :=
  for $privilege-row in $privilege-rows
  let $privilege-id := map:get($privilege-row, "privilegeId")
  let $ordinality := map:get($privilege-row, "ordinality")
  let $privilege-name := xdmp:privilege-name(xs:unsignedLong($privilege-id))
  let $uri := "/cleverllamas/llamaverse/scratch/optic-update/privileges/" || $user-name || "-" || fn:string($ordinality) || ".json"
  return
    map:entry("uri", $uri)
      => map:with("doc", object-node {
           "user": $user-name,
           "privilegeId": fn:string($privilege-id),
         "ordinality": $ordinality,
           "privilegeName": $privilege-name,
           "source": "op-execute-privilege-snapshot"
         })
      => map:with("collections", ("optic-execute-demo", "optic-privilege-snapshot"))

let $_ :=
  op:from-param("bindingParam", (), op:doc-col-types())
    => op:write()
    => op:execute(
         map:entry("bindingParam", $rows),
         ("trace=opticPrivilegeSnapshot", "optimize=1")
       )

return
  <result>
    <user>{ $user-name }</user>
    <written>{ count($rows) }</written>
    <samples>{
      for $row in subsequence($rows, 1, 4)
      return
        <sample>
          <uri>{ map:get($row, "uri") }</uri>
          <doc>{ xdmp:to-json-string(map:get($row, "doc")) }</doc>
        </sample>
    }</samples>
  </result>